# Copyright (c) 2016 The WebRTC project authors. All Rights Reserved.
#
# Use of this source code is governed by a BSD-style license
# that can be found in the LICENSE file in the root of the source
# tree. An additional intellectual property rights grant can be found
# in the file PATENTS.  All contributing project authors may
# be found in the AUTHORS file in the root of the source tree.

import("../webrtc.gni")

rtc_library("rtc_stats_test_utils") {
  visibility = [ "*" ]
  cflags = []
  sources = [
    "test/rtc_test_stats.cc",
    "test/rtc_test_stats.h",
  ]

  deps = [
    "../api:rtc_stats_api",
    "../api/units:timestamp",
    "../rtc_base:checks",
    "../rtc_base/system:rtc_export",
  ]
}

if (rtc_include_tests && !build_with_chromium) {
  rtc_cc_test("rtc_stats_report_unittest") {
    sources = [ "rtc_stats_report_unittest.cc" ]
    deps = [
      "../api:rtc_stats_api",
      "../api:scoped_refptr",
      "../api/units:timestamp",
      "../test:test_support",
    ]
  }

  rtc_cc_test("rtc_stats_unittest") {
    sources = [ "rtc_stats_unittest.cc" ]
    deps = [
      ":rtc_stats_test_utils",
      "../api:rtc_stats_api",
      "../api/units:timestamp",
      "../rtc_base:checks",
      "../rtc_base:rtc_json",
      "../test:test_support",
    ]
  }

  rtc_test_suite("rtc_stats_unittests") {
    tests = [
      ":rtc_stats_report_unittest",
      ":rtc_stats_unittest",
    ]
  }
}