# Copyright (c) 2019 The WebRTC project authors. All Rights Reserved.
#
# Use of this source code is governed by a BSD-style license
# that can be found in the LICENSE file in the root of the source
# tree. An additional intellectual property rights grant can be found
# in the file PATENTS.  All contributing project authors may
# be found in the AUTHORS file in the root of the source tree.

import("../../webrtc.gni")

rtc_library("repeating_task") {
  sources = [
    "repeating_task.cc",
    "repeating_task.h",
  ]
  deps = [
    "..:logging",
    "..:timeutils",
    "../../api:sequence_checker",
    "../../api/task_queue",
    "../../api/task_queue:pending_task_safety_flag",
    "../../api/task_queue:to_queued_task",
    "../../api/units:time_delta",
    "../../api/units:timestamp",
    "../../system_wrappers:system_wrappers",
  ]
  absl_deps = [ "//third_party/abseil-cpp/absl/memory" ]
}

rtc_library("pending_task_safety_flag") {
  sources = [ "pending_task_safety_flag.h" ]
  deps = [ "../../api/task_queue:pending_task_safety_flag" ]
}

rtc_source_set("to_queued_task") {
  sources = [ "to_queued_task.h" ]
  deps = [ "../../api/task_queue:to_queued_task" ]
}

if (rtc_include_tests) {
  rtc_library("repeating_task_unittests") {
    testonly = true
    sources = [ "repeating_task_unittest.cc" ]
    deps = [
      ":repeating_task",
      "..:rtc_event",
      "..:rtc_task_queue",
      "..:task_queue_for_test",
      "../../api/task_queue",
      "../../api/task_queue:to_queued_task",
      "../../api/units:timestamp",
      "../../system_wrappers:system_wrappers",
      "../../test:test_support",
    ]
  }
}