| # Copyright (c) 2014 The WebRTC project authors. All Rights Reserved. |
| # |
| # Use of this source code is governed by a BSD-style license |
| # that can be found in the LICENSE file in the root of the source |
| # tree. An additional intellectual property rights grant can be found |
| # in the file PATENTS. All contributing project authors may |
| # be found in the AUTHORS file in the root of the source tree. |
| |
| import("../webrtc.gni") |
| |
| rtc_static_library("video") { |
| sources = [ |
| "call_stats.cc", |
| "call_stats.h", |
| "encoder_rtcp_feedback.cc", |
| "encoder_rtcp_feedback.h", |
| "overuse_frame_detector.cc", |
| "overuse_frame_detector.h", |
| "payload_router.cc", |
| "payload_router.h", |
| "quality_threshold.cc", |
| "quality_threshold.h", |
| "receive_statistics_proxy.cc", |
| "receive_statistics_proxy.h", |
| "report_block_stats.cc", |
| "report_block_stats.h", |
| "rtp_streams_synchronizer.cc", |
| "rtp_streams_synchronizer.h", |
| "rtp_video_stream_receiver.cc", |
| "rtp_video_stream_receiver.h", |
| "send_delay_stats.cc", |
| "send_delay_stats.h", |
| "send_statistics_proxy.cc", |
| "send_statistics_proxy.h", |
| "stats_counter.cc", |
| "stats_counter.h", |
| "stream_synchronization.cc", |
| "stream_synchronization.h", |
| "transport_adapter.cc", |
| "transport_adapter.h", |
| "video_receive_stream.cc", |
| "video_receive_stream.h", |
| "video_send_stream.cc", |
| "video_send_stream.h", |
| "video_stream_decoder.cc", |
| "video_stream_decoder.h", |
| "video_stream_encoder.cc", |
| "video_stream_encoder.h", |
| ] |
| |
| if (!build_with_chromium && is_clang) { |
| # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163). |
| suppressed_configs += [ "//build/config/clang:find_bad_constructs" ] |
| } |
| |
| deps = [ |
| "..:webrtc_common", |
| "../api:optional", |
| "../api:transport_api", |
| "../api/video_codecs:video_codecs_api", |
| "../call:bitrate_allocator", |
| "../call:call_interfaces", |
| "../call:rtp_interfaces", |
| "../call:video_stream_api", |
| |
| # For RtxReceiveStream. |
| "../call:rtp_receiver", |
| "../common_video", |
| "../logging:rtc_event_log_api", |
| "../media:rtc_media_base", |
| "../modules:module_api", |
| "../modules/bitrate_controller", |
| "../modules/congestion_controller", |
| "../modules/pacing", |
| "../modules/remote_bitrate_estimator", |
| "../modules/rtp_rtcp", |
| "../modules/utility", |
| "../modules/video_coding", |
| "../modules/video_coding:video_coding_utility", |
| "../modules/video_coding:webrtc_vp8", |
| "../modules/video_processing", |
| "../rtc_base:rtc_base_approved", |
| "../rtc_base:rtc_numerics", |
| "../rtc_base:rtc_task_queue", |
| "../rtc_base:sequenced_task_checker", |
| "../rtc_base:weak_ptr", |
| "../system_wrappers", |
| "../voice_engine", |
| ] |
| } |
| |
| if (rtc_include_tests) { |
| rtc_source_set("video_quality_test") { |
| testonly = true |
| visibility = [ ":*" ] # Only targets in this file can depend on this. |
| sources = [ |
| "video_quality_test.cc", |
| "video_quality_test.h", |
| ] |
| deps = [ |
| "../api:optional", |
| "../call:call_interfaces", |
| "../common_video", |
| "../logging:rtc_event_log_api", |
| "../media:rtc_media", |
| "../media:rtc_media_base", |
| "../modules/audio_mixer:audio_mixer_impl", |
| "../modules/rtp_rtcp", |
| "../modules/video_coding:webrtc_h264", |
| "../modules/video_coding:webrtc_vp8", |
| "../modules/video_coding:webrtc_vp9", |
| "../rtc_base:rtc_base_approved", |
| "../rtc_base:rtc_base_tests_utils", |
| "../rtc_base:rtc_task_queue", |
| "../system_wrappers", |
| "../test:rtp_test_utils", |
| "../test:test_common", |
| "../test:test_renderer", |
| "../test:test_renderer", |
| "../test:test_support", |
| "../test:test_support_test_artifacts", |
| "../test:video_test_common", |
| "../test:video_test_common", |
| "../test:video_test_support", |
| "../voice_engine", |
| "//testing/gtest", |
| ] |
| if (!build_with_chromium && is_clang) { |
| # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163). |
| suppressed_configs += [ "//build/config/clang:find_bad_constructs" ] |
| } |
| } |
| |
| rtc_source_set("video_full_stack_tests") { |
| testonly = true |
| |
| # Skip restricting visibility on mobile platforms since the tests on those |
| # gets additional generated targets which would require many lines here to |
| # cover (which would be confusing to read and hard to maintain). |
| if (!is_android && !is_ios) { |
| visibility = [ "..:webrtc_perf_tests" ] |
| } |
| sources = [ |
| "full_stack_tests.cc", |
| ] |
| deps = [ |
| ":video_quality_test", |
| "../modules/pacing:pacing", |
| "../test:field_trial", |
| "../test:test_common", |
| "../test:test_support", |
| "//testing/gtest", |
| ] |
| if (!build_with_chromium && is_clang) { |
| # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163). |
| suppressed_configs += [ "//build/config/clang:find_bad_constructs" ] |
| } |
| if (rtc_use_h264) { |
| defines = [ "WEBRTC_USE_H264" ] |
| } |
| } |
| |
| rtc_executable("video_loopback") { |
| testonly = true |
| sources = [ |
| "video_loopback.cc", |
| ] |
| deps = [ |
| ":video_quality_test", |
| "../rtc_base:rtc_base_approved", |
| "../system_wrappers:metrics_default", |
| "../test:field_trial", |
| "../test:run_test", |
| "../test:run_test_interface", |
| "../test:test_common", |
| "../test:test_renderer", |
| "../test:test_support", |
| "//testing/gmock", |
| "//testing/gtest", |
| ] |
| if (!build_with_chromium && is_clang) { |
| # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163). |
| suppressed_configs += [ "//build/config/clang:find_bad_constructs" ] |
| } |
| } |
| |
| rtc_executable("screenshare_loopback") { |
| testonly = true |
| sources = [ |
| "screenshare_loopback.cc", |
| ] |
| |
| deps = [ |
| ":video_quality_test", |
| "../rtc_base:rtc_base_approved", |
| "../system_wrappers:metrics_default", |
| "../test:field_trial", |
| "../test:run_test", |
| "../test:run_test_interface", |
| "../test:test_common", |
| "../test:test_renderer", |
| "../test:test_support", |
| ] |
| if (!build_with_chromium && is_clang) { |
| # Suppress warnings from Chrome's Clang plugins. |
| # See http://code.google.com/p/webrtc/issues/detail?id=163 for details. |
| suppressed_configs += [ "//build/config/clang:find_bad_constructs" ] |
| } |
| } |
| |
| rtc_executable("video_replay") { |
| testonly = true |
| sources = [ |
| "replay.cc", |
| ] |
| deps = [ |
| "..:webrtc_common", |
| "../api/video_codecs:video_codecs_api", |
| "../call:call_interfaces", |
| "../common_video", |
| "../logging:rtc_event_log_api", |
| "../modules/rtp_rtcp", |
| "../rtc_base:rtc_base_approved", |
| "../system_wrappers", |
| "../system_wrappers:metrics_default", |
| "../test:field_trial", |
| "../test:rtp_test_utils", |
| "../test:run_test", |
| "../test:run_test_interface", |
| "../test:test_common", |
| "../test:test_renderer", |
| "../test:test_support", |
| "../test:video_test_common", |
| "../test:video_test_support", |
| ] |
| if (!build_with_chromium && is_clang) { |
| # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163). |
| suppressed_configs += [ "//build/config/clang:find_bad_constructs" ] |
| } |
| } |
| |
| # TODO(pbos): Rename test suite. |
| rtc_source_set("video_tests") { |
| testonly = true |
| |
| # Skip restricting visibility on mobile platforms since the tests on those |
| # gets additional generated targets which would require many lines here to |
| # cover (which would be confusing to read and hard to maintain). |
| if (!is_android && !is_ios) { |
| visibility = [ "..:video_engine_tests" ] |
| } |
| defines = [] |
| sources = [ |
| "call_stats_unittest.cc", |
| "encoder_rtcp_feedback_unittest.cc", |
| "end_to_end_tests.cc", |
| "overuse_frame_detector_unittest.cc", |
| "payload_router_unittest.cc", |
| "picture_id_tests.cc", |
| "quality_threshold_unittest.cc", |
| "receive_statistics_proxy_unittest.cc", |
| "report_block_stats_unittest.cc", |
| "rtp_video_stream_receiver_unittest.cc", |
| "send_delay_stats_unittest.cc", |
| "send_statistics_proxy_unittest.cc", |
| "stats_counter_unittest.cc", |
| "stream_synchronization_unittest.cc", |
| "video_receive_stream_unittest.cc", |
| "video_send_stream_tests.cc", |
| "video_stream_encoder_unittest.cc", |
| ] |
| deps = [ |
| ":video", |
| "../api:optional", |
| "../api:video_frame_api", |
| "../api/video_codecs:video_codecs_api", |
| "../call:call_interfaces", |
| "../call:mock_rtp_interfaces", |
| "../call:rtp_receiver", |
| "../call:rtp_sender", |
| "../call:video_stream_api", |
| "../common_video", |
| "../logging:rtc_event_log_api", |
| "../media:rtc_media", |
| "../media:rtc_media_base", |
| "../media:rtc_media_tests_utils", |
| "../modules:module_api", |
| "../modules/pacing", |
| "../modules/rtp_rtcp", |
| "../modules/rtp_rtcp:mock_rtp_rtcp", |
| "../modules/utility", |
| "../modules/video_coding", |
| "../modules/video_coding:video_coding_utility", |
| "../modules/video_coding:webrtc_h264", |
| "../modules/video_coding:webrtc_vp8", |
| "../modules/video_coding:webrtc_vp9", |
| "../rtc_base:rtc_base_approved", |
| "../rtc_base:rtc_base_tests_utils", |
| "../rtc_base:rtc_numerics", |
| "../system_wrappers", |
| "../system_wrappers:field_trial_default", |
| "../system_wrappers:metrics_api", |
| "../system_wrappers:metrics_default", |
| "../test:direct_transport", |
| "../test:field_trial", |
| "../test:rtp_test_utils", |
| "../test:test_common", |
| "../test:test_support", |
| "../test:video_test_common", |
| "//testing/gmock", |
| "//testing/gtest", |
| ] |
| if (!build_with_chromium && is_clang) { |
| # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163). |
| suppressed_configs += [ "//build/config/clang:find_bad_constructs" ] |
| } |
| if (rtc_use_h264) { |
| defines += [ "WEBRTC_USE_H264" ] |
| } |
| } |
| } |
