libjingle/BUILD.gn

# Copyright (c) 2016 The WebRTC project authors. All Rights Reserved.
#
# Use of this source code is governed by a BSD-style license
# that can be found in the LICENSE file in the root of the source
# tree. An additional intellectual property rights grant can be found
# in the file PATENTS.  All contributing project authors may
# be found in the AUTHORS file in the root of the source tree.

import("../build/webrtc.gni")

group("libjingle") {
  public_deps = [
    "xmllite",
    "xmpp",
  ]
}

if (rtc_include_tests) {
  rtc_test("xmllite_xmpp_unittests") {
    configs += [ "..:rtc_unittests_config" ]

    if (!build_with_chromium && is_clang) {
      # Suppress warnings from the Chromium Clang plugin.
      # See http://code.google.com/p/webrtc/issues/detail?id=163 for details.
      suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
    }

    deps = [
      "../base:rtc_base_tests_utils",
      "xmllite",
      "xmpp",
      "//testing/gtest",
    ]

    sources = [
      "xmllite/qname_unittest.cc",
      "xmllite/xmlbuilder_unittest.cc",
      "xmllite/xmlelement_unittest.cc",
      "xmllite/xmlnsstack_unittest.cc",
      "xmllite/xmlparser_unittest.cc",
      "xmllite/xmlprinter_unittest.cc",
      "xmpp/fakexmppclient.h",
      "xmpp/hangoutpubsubclient_unittest.cc",
      "xmpp/jid_unittest.cc",
      "xmpp/mucroomconfigtask_unittest.cc",
      "xmpp/mucroomdiscoverytask_unittest.cc",
      "xmpp/mucroomlookuptask_unittest.cc",
      "xmpp/mucroomuniquehangoutidtask_unittest.cc",
      "xmpp/pingtask_unittest.cc",
      "xmpp/pubsubclient_unittest.cc",
      "xmpp/pubsubtasks_unittest.cc",
      "xmpp/util_unittest.cc",
      "xmpp/util_unittest.h",
      "xmpp/xmppengine_unittest.cc",
      "xmpp/xmpplogintask_unittest.cc",
      "xmpp/xmppstanzaparser_unittest.cc",
    ]
  }
}